VB [SQL Server 2008版] サンプルプログラム

あらかじめ検索用のボタンと、データ表示用のデータグリッドビューを、フォームに貼り付ける。

• SqlDataAdapter.Fillでレコード取得
• DataGridViewのDatasourceプロパティでデータをバインド
• データグリッドビューに商品マスター表の全レコードを表示（レコードが多すぎると表示に時間がかかるので注意）
• 接続文字列を アプリケーション構成ファイル（app.config）から取得
• 販売管理データベースはこちら

VB 2008 [MDB版]

OleDbDataAdapter.Fillでレコードを取得するサンプル

Option Strict On
Imports System.Data.SqlClient
Imports System.Configuration  ' 参照の追加 System.Configuration

Public Class Form1

    '****************************************************************
    ' 検索ボタン押下処理
    '****************************************************************
    Private Sub Button1_Click( _
        ByVal sender As System.Object, _
        ByVal e As System.EventArgs) Handles Button1.Click

        Try
            Using con As New SqlConnection
              Using cmd As New SqlCommand
                  ' 接続文字列をapp.configファイルから取得
                  ' （SQL Server 2008 Express Edition）
                  Dim settings As ConnectionStringSettings
                  settings = _
                      ConfigurationManager.ConnectionStrings _
                      ("販売管理ConnectionString")

                  If settings Is Nothing Then
                      ' 接続文字列取得エラー
                      MessageBox.Show("接続文字列がapp.configに未登録")
                  Else
                      ' 接続文字列の設定
                      con.ConnectionString = settings.ConnectionString

                      ' SqlCommand.Connectionプロパティの設定
                      cmd.Connection = con
                  End If

                  ' SQL文の設定
                  cmd.CommandText = _
                      "SELECT 商品コード, 商品名称, 販売単価 " & _
                      "FROM 商品マスター表 ORDER BY 商品コード"

                  ' 商品マスター表からレコード取得
                  Dim dt As New DataTable
                  Using da As New SqlDataAdapter
                      da.SelectCommand = cmd
                      da.Fill(dt)
                      ' データグリッドビューにバインド
                      Me.DataGridView1.DataSource = dt
                  End Using
              End Using
            End Using
        Catch ex As Exception
            ' 例外が発生した時の処理
            MessageBox.Show(ex.ToString)
        End Try

    End Sub

End Class